<% @LANGUAGE = VBScript %>
<% ' wuf48.asp
Option Explicit
Response.Expires = 0
%>
<!--#include file="adovbs.inc"-->
<%
'第一部分: 建立连接
Dim Cnn, StrCnn
Set Cnn = Server.CreateObject("ADODB.Connection")
StrCnn = "Provider = Microsoft.Jet.OLEDB.4.0; Data Source = C:\Inetpub\home\asp\Northwind.mdb"
Cnn.Open StrCnn
'第二部分: 通过创建 RecordSet 对象得到记录集
Dim rsTest
Set rsTest = Server.CreateObject("ADODB.Recordset")
rsTest.Open "运货商",Cnn,adOpenForwardOnly,adLockReadOnly,adCmdTable
%>
<HTML>
<BODY>
<% '第三部分: 将得到的记录集显示到浏览器上
Do While Not rsTest.EOF
Response.Write rsTest(0) & " " & rsTest(1) & " " & rsTest(2) & " " & "<BR>"
rsTest.MoveNext
Loop
'第四部分: 打扫战场
rsTest.Close: Cnn.Close
Set rsTest = Nothing: Set Cnn = Nothing
%>
</BODY>
</HTML>
分析：
1．首先看看关键句：
rsTest.Open "运货商",Cnn,adOpenForwardOnly,adLockReadOnly,adCmdTable
第一个参数可以是表名（如：运货商），也可以是SQL语句（如wuf45.asp）。
第二个参数指定当前的连接。
第三个参数指示CursorType，确定提供者打开 Recordset 时应该使用的游标类型。这里采用仅向前移动的游标。
第四个参数指示LockType，确定提供者打开 Recordset 时应该使用的锁定（并发）类型。这里指定为只读。
第五个参数与第一个参数相关，如本例中第一个参数为表名，则第五个参数使用adCmdTable，若第一个参数为SQL语句，则第该参数为adCmdText，如：
rsTest.Open "Select * From 运货商",Cnn,adOpenForwardOnly,adLockReadOnly,adCmdText
我想不见得大部人都能真正搞懂这五个参数的意思，没关系，刚开始只要照搬会用就行，以后我们会不断接触，熟了便能生巧。
关于CursorType和LockType这两个参数，将在下讲详细阐述，仅仅检索数据只需按本例设置就可以了。
2．这五个参数，也可以利用Recordset对象的属性来设置，如例wuf46.asp。
'第二部分: 通过创建 RecordSet 对象得到记录集
Dim rsTest
Set rsTest = Server.CreateObject("ADODB.Recordset")
rsTest.ActiveConnection = Cnn
rsTest.CursorType = adOpenForwardOnly
rsTest.LockType = adLockReadOnly
rsTest.Open "运货商", , , ,adCmdTable
3． 再看看这句：<!--#include file="adovbs.inc"-->。
（1） 因为使用了adOpenForwardOnly,adLockReadOnly,adCmdText这样的常数，所以需要将adovbs.inc这个文件包含进来。
（2） adovbs.inc这个文件一般位于目录Program Files\Common Files\SYSTEM\ADO下，你可将它拷至Web服务器当前目录（本讲下载包中也有该文件）。
（3） 用记事本打开这个文件看一下，就明白为什么需要这个文件了。
方法三：通过引入 Command 对象——这个应该在你有能力的前提下研究。
<% @LANGUAGE = VBScript %>
<% ' wuf47.asp
Option Explicit
Response.Expires = 0
%>
<!--#include file="adovbs.inc"-->
<%
'第一部分: 建立连接
Dim Cnn, StrCnn
Set Cnn = Server.CreateObject("ADODB.Connection")
StrCnn = "Provider = Microsoft.Jet.OLEDB.4.0; Data Source = C:\Inetpub\home\asp\Northwind.mdb"
Cnn.Open StrCnn
'第二部分: 通过创建 Command 对象得到记录集
Dim StrSQL, rsTest, cmdTest
'创建 Command 对象
Set cmdTest = Server.CreateObject("ADODB.Command")
StrSQL = "SELECT MAX(数量) FROM 订单明细"
cmdTest.CommandText = StrSQL
cmdTest.CommandType = adCmdText '表明命令类型为 SQL 语句 |
